home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d27 / ddsgen.arc / DDSC.CLP next >
Encoding:
Text File  |  1991-12-04  |  12.0 KB  |  152 lines
  1. /*------------------------------------------------------------------*/          
  2. /*  PROGRAM NAME: DDSC01                                            */          
  3. /*  PURPOSE     : CPP FOR DDSGEN COMMAND                            */          
  4. /*  TYPE        : CL PROGRAM                                        */          
  5. /*                                                                  */          
  6. /*  AUTHOR      : TERRENCE W. MOYER                                 */          
  7. /*                55 KEPPEL AVE                                     */          
  8. /*                WEST LAWN, PA. 19609                              */          
  9. /*                                                                  */          
  10. /*  DATE        : NOVEMBER 1, 1986                                  */          
  11. /*                                                                  */          
  12. /*  *LDA USAGE  : THE FOLLOWING POSITIONS OF THE *LDA ARE RESERVED  */          
  13. /*                BY THE DDS GENERATOR SYSTEM FOR THE FOLLOWING     */          
  14. /*                PURPOSE.                                          */          
  15. /*    1 - 100  ....................INPUT  FILE DATA                 */          
  16. /*  101 - 200  ....................SOURCE FILE DATA                 */          
  17. /*  201 - 300  ....................MISCELLANEOUS SYSTEM DATA        */          
  18. /*                                                                  */          
  19. /*    1 -  10  &INFIL              INPUT FILE NAME                  */          
  20. /*   11 -  20  &INLIB              INPUT FILE LIBRARY               */
  21. /*   21 -  26  %SST(&WHCRTD 2 6)   FILE CREATE DATE  (YYMMDD)       */          
  22. /*   27 -  32  &PHFCTM             FILE CREATE TIME  (HHMMSS)       */          
  23. /*   33 -  33  &WHFTYP             FILE TYPE - P,L,D (PHY/LGL/DEV)  */          
  24. /*   51 - 100  &PHTXT              FILE LEVEL TEXT                  */          
  25. /*  101 - 110  &SRCFIL             SOURCE FILE NAME                 */          
  26. /*  111 - 120  &SRCLIB             SOURCE FILE LIBRARY              */          
  27. /*  121 - 130  &SRCFIL             SOURCE FILE MEMBER               */          
  28. /*  201 - 206                      CURRENT SOURCE SEQUENCE NUMBER.  */          
  29. /*  207 - 212                      DDS SOURCE DATE   (YYMMDD).      */          
  30. /*                                                                  */          
  31. /*  EXTERNAL SWITCHES:                                              */          
  32. /*                                                                  */          
  33. /*  SWITCH 1 - CONTROLS REFERENCE/NO REFERENCE GENERATION.          */          
  34. /*  SWITCH 2 - CONTROLS TEXT/NO TEXT GENERATION.                    */          
  35. /*             (NOTE: TEXT IS ONLY SUPPRESSED IF COLHDG EXISTS)     */          
  36. /*                                                                  */          
  37. /*------------------------------------------------------------------*/          
  38.  PGM         PARM(&INFILENAM &SRCFILENAM &SRCMBR &REF &TEXT)                    
  39.              DCLF FILE(QADSPFFD.QSYS)                                           
  40.              DCL VAR(&INFILENAM)  TYPE(*CHAR) LEN(20)
  41.              DCL VAR(&SRCFILENAM) TYPE(*CHAR) LEN(20)                           
  42.              DCL VAR(&INFIL)      TYPE(*CHAR) LEN(10)                           
  43.              DCL VAR(&INLIB)      TYPE(*CHAR) LEN(10)                           
  44.              DCL VAR(&SRCFIL)     TYPE(*CHAR) LEN(10)                           
  45.              DCL VAR(&SRCLIB)     TYPE(*CHAR) LEN(10)                           
  46.              DCL VAR(&SRCMBR)     TYPE(*CHAR) LEN(10)                           
  47.              DCL VAR(&REF)        TYPE(*CHAR) LEN(5)                            
  48.              DCL VAR(&TEXT)       TYPE(*CHAR) LEN(6)                            
  49.              DCL VAR(&FTYPE)      TYPE(*CHAR) LEN(4)                            
  50.              DCL VAR(&SWS)        TYPE(*CHAR) LEN(8)                            
  51.              DCL VAR(&MSGID)      TYPE(*CHAR) LEN(7)                            
  52.              DCL VAR(&MSGDTA)     TYPE(*CHAR) LEN(80)                           
  53.                                                                                 
  54.              MONMSG     MSGID(CPF0000) EXEC(GOTO RCVMSGS)                       
  55.                                                                                 
  56.              RMVMSG     CLEAR(*ALL) /* CLEAR PGM MSGQ BEFORE BEGIN */           
  57.              RTVJOBA    SWS(&SWS)                                               
  58.              OVRDBF     FILE(QADSPFFD) TOFILE(TEMP.QTEMP)                       
  59.                                                                                 
  60.              CHGVAR     VAR(&INFIL)  VALUE(%SST(&INFILENAM   1 10))
  61.              CHGVAR     VAR(&INLIB)  VALUE(%SST(&INFILENAM  11 10))             
  62.              CHGVAR     VAR(&SRCFIL) VALUE(%SST(&SRCFILENAM  1 10))             
  63.              CHGVAR     VAR(&SRCLIB) VALUE(%SST(&SRCFILENAM 11 10))             
  64.                                                                                 
  65.              IF         COND(&SRCLIB = '*FILE') THEN(CHGVAR +                   
  66.                         VAR(&SRCLIB) VALUE(&INLIB))                             
  67.              IF         COND(%SST(&REF 1 1) = 'R') THEN(CHGJOB +                
  68.                         SWS(0XXXXXXX))        /* USE REFFLD FUNCTION */         
  69.              ELSE       CHGJOB SWS(1XXXXXXX)  /*  NO REFFLD FUNCTION */         
  70.              IF         COND(%SST(&TEXT 1 1)= 'T') THEN(CHGJOB +                
  71.                         SWS(X0XXXXXX))        /* GENERATE TEXT */               
  72.              ELSE       CHGJOB SWS(X1XXXXXX)  /* NO TEXT       */               
  73.                                                                                 
  74.  /* CHECK INPUT FILE AND SOURCE FILE EXISTENCE */                               
  75.              SNDPGMMSG  MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA('DDSGEN - +         
  76.                           Checking input values') TOPGMQ(*EXT) +                
  77.                           MSGTYPE(*STATUS)                                      
  78.              CHKOBJ     OBJ(&INFIL.&INLIB)    OBJTYPE(*FILE)                    
  79.              CALL       DDS01CSRC (&SRCFIL &SRCLIB)                             
  81.              IF         COND(&SRCLIB = '*LIBL') THEN(RTVDTAARA +                
  82.                         DTAARA(*LDA (111 10)) RTNVAR(&SRCLIB))                  
  83.                                                                                 
  84.              DSPFFD     FILE(&INFIL.&INLIB) OUTPUT(*NONE) +                     
  85.                         OUTFILE(TEMP.QTEMP)                                     
  86.              RCVF                                                               
  87.              DLTOVR     QADSPFFD                                                
  88.              IF         COND(&INLIB = '*LIBL') THEN(CHGVAR +                    
  89.                         VAR(&INLIB) VALUE(&WHLIB))                              
  90.                                                                                 
  91. /* SET UP THE *LDA */                                                           
  92.              CHGDTAARA  DTAARA(*LDA (  1 10)) VALUE(&INFIL)                     
  93.              CHGDTAARA  DTAARA(*LDA ( 11 10)) VALUE(&INLIB)                     
  94.              CHGDTAARA  DTAARA(*LDA ( 21  6)) VALUE(%SST(&WHCRTD 2 6))          
  95.              CHGDTAARA  DTAARA(*LDA ( 27  6)) VALUE('000000')                   
  96.              CHGDTAARA  DTAARA(*LDA ( 33  1)) VALUE(&WHFTYP)                    
  97.              CHGDTAARA  DTAARA(*LDA (101 10)) VALUE(&SRCFIL)                    
  98.              CHGDTAARA  DTAARA(*LDA (111 10)) VALUE(&SRCLIB)                    
  99.              CHGDTAARA  DTAARA(*LDA (121 10)) VALUE(&SRCMBR)                    
  101. /* VERIFY FILE TYPE IS SUPPORTED BY GENERATOR. */                               
  102.              IF         COND(&WHFTYP *NE 'P') THEN(DO)                          
  103.              IF         (&WHFTYP *EQ 'L') THEN(CHGVAR &FTYPE '*LGL')            
  104.              ELSE  IF   (&WHFTYP *EQ 'D') THEN(CHGVAR &FTYPE '*DEV')            
  105.              SNDPGMMSG  MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA(&FTYPE +            
  106.                           *CAT ' file type not supported by DDS +               
  107.                           generator')                                           
  108.              GOTO ENDPGM                                                        
  109.              ENDDO                                                              
  110.                                                                                 
  111.  /* CHECK FOR SOURCE MEMBER EXISTENCE - ADD MEMBER IF NOT FOUND */              
  112.  /* CLEAR MEMBER.                                             */                
  113.              IF         COND(&SRCMBR = '*FILE') THEN(CHGVAR +                   
  114.                         VAR(&SRCMBR) VALUE(&INFIL))                             
  115.              CHKOBJ     OBJ(&SRCFIL.&SRCLIB) OBJTYPE(*FILE) +                   
  116.                         MBR(&SRCMBR)                                            
  117.              MONMSG     MSGID(CPF9815) EXEC(DO) /* Member not found. */         
  118.              ADDPFM     FILE(&SRCFIL.&SRCLIB) MBR(&SRCMBR) +                    
  119.                         TEXT('DDS for ' *cat &INFIL *tcat '.' +                 
  120.                               *cat &INLIB)
  121.                         ENDDO                                                   
  122.              CLRPFM     FILE(&SRCFIL.&SRCLIB) MBR(&SRCMBR)                      
  123.              RMVMSG     CLEAR(*ALL) /* RMV ADDPFM AND CLRPFM MSGS */            
  124.                                                                                 
  125. /* CALL APPROPRIATE GENERATOR */                                                
  126.              SNDPGMMSG  MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA('Checking +         
  127.                           complete.  Working') TOPGMQ(*EXT) +                   
  128.                           MSGTYPE(*STATUS)                                      
  129.              IF   (&WHFTYP *EQ 'P') THEN(DO)                                    
  130.              CALL DDS01CPF PARM(&INFIL &INLIB &SRCFIL &SRCLIB &SRCMBR)          
  131.              ENDDO  /*  PHYSICAL FILE  GENERATOR */                             
  132.                                                                                 
  133.  GOTO ENDPGM                                                                    
  134.                                                                                 
  135. /*       *** RECEIVE AND DISPLAY MONITORED ERROR MESSAGES. ***                */
  136.  RCVMSGS:    RMVMSG     PGMQ(*EXT)  CLEAR(*ALL)                                 
  137.  RCV1:       RCVMSG     MSGDTA(&MSGDTA) MSGID(&MSGID)                           
  138.              IF         COND(&MSGID = ' ') THEN(DO)                             
  139.                         SNDPGMMSG MSG(' ') TOPGMQ(*EXT)                         
  140.                         GOTO  ENDPGM
  141.                         ENDDO                                                   
  142.              ELSE       DO                                                      
  143.              SNDPGMMSG  MSGID(&MSGID) MSGF(QCPFMSG) MSGDTA(&MSGDTA) +           
  144.                         TOPGMQ(*EXT) MSGTYPE(*COMP)                             
  145.                         GOTO   RCV1                                             
  146.              ENDDO                                                              
  147.                                                                                 
  148. ENDPGM:      DLTOVR     *ALL                                                    
  149.              CHGJOB     SWS(&SWS)                                               
  150.              ENDPGM
  151. 
  152.